Use the Smith Decomposition to Analyze a Lattice
Consider the lattice generated by integer multiples of the vectors
and
.
In[1]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_91.png)
b1 = {3, -3};
b2 = {2, 1};
In[2]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_92.png)
ptsb = Flatten[Table[j b1 + k b2, {j, -12, 12}, {k, -12, 12}], 1];
In[3]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_93.png)
graphicsb =
Graphics[{Blue, PointSize[Large], Point@ptsb}, PlotRange -> 10,
Axes -> True]
Out[3]=
![](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/O_81.png)
Let be the matrix whose rows are
and
.
In[4]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_94.png)
m = {b1, b2};
The Smith decomposition gives three matrices that satisfy the identity .
In[5]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_95.png)
{u, r, v} = SmithDecomposition[m];
In[6]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_96.png)
u.m.v == r
Out[6]=
![](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/O_82.png)
The matrices and
have integer entries and determinant one.
In[7]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_97.png)
{u // MatrixForm, v // MatrixForm, Det[u], Det[v]}
Out[7]=
![](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/O_83.png)
The matrix is integer and diagonal. From its entries it can be seen that the structure of the group
is
or simply
, as
is the trivial group.
In[8]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_98.png)
r // MatrixForm
Out[8]//MatrixForm=
![](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/O_84.png)
Multiplying the identity on the right by
gives
. Because
is integer and determinant
,
generates the same lattice as
but is simpler.
In[9]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_99.png)
g = r.Inverse[v];
g // MatrixForm
Out[9]//MatrixForm=
![](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/O_85.png)
Visualize the lattice generated by the rows of .
In[10]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_100.png)
ptsg = Flatten[
Table[j First[g] + k Last[g], {j, -12, 12}, {k, -12, 12}], 1];
In[11]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_101.png)
graphicsg =
Graphics[{Red, PointSize[Medium], Point@ptsg}, PlotRange -> 10,
Axes -> True]
Out[11]=
![](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/O_86.png)
Superimposing the new lattice on the original confirms that they are the same.
In[12]:=
![Click for copyable input](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/In_102.png)
Show[{graphicsb, graphicsg}]
Out[12]=
![](assets.en/use-the-smith-decomposition-to-analyze-a-lattice/O_87.png)