Encontre as funções simbólicas próprias de um laplaciano em 1D
Especifique um operador laplaciano em 1D.
In[1]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_81.png)
\[ScriptCapitalL] = -Laplacian[u[x], {x}];
Especifique as condições de contorno de Dirichlet homogêneos para as funções próprias.
In[2]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_82.png)
\[ScriptCapitalB]1 = DirichletCondition[u[x] == 0, True];
Encontre os cinco menores valores e funções próprios.
In[3]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_83.png)
{vals, funs} =
DEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]1},
u[x], {x, 0, \[Pi]}, 5];
Inspecione os valores próprios.
In[4]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_84.png)
vals
Out[4]=
![](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/O_37.png)
Inspecione as funções próprias.
In[5]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_85.png)
funs
Out[5]=
![](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/O_38.png)
Visualize as funções próprias.
In[6]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_86.png)
Plot[Evaluate[funs + 2 Range[5]], {x, 0, \[Pi]}]
Out[6]=
![](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/O_39.png)
Especifique uma condição de contorno de Neumann homogêneo.
In[7]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_87.png)
\[ScriptCapitalB]2 = NeumannValue[0, True];
Encontre os cinco menores valores e funções próprios.
In[8]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_88.png)
{vals, funs} =
DEigensystem[\[ScriptCapitalL] + \[ScriptCapitalB]2,
u[x], {x, 0, \[Pi]}, 5];
Inspecione os valores próprios. Em relação às condições de Dirichlet, um modo zero foi adicionado.
In[9]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_89.png)
vals
Out[9]=
![](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/O_40.png)
Senos têm substituído cossenos nas funções próprias.
In[10]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_90.png)
funs
Out[10]=
![](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/O_41.png)
Visualize as funções próprias.
In[11]:=
![Click for copyable input](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/In_91.png)
Plot[Evaluate[funs + 2 Range[5]], {x, 0, \[Pi]}]
Out[11]=
![](assets.pt-br/find-a-1d-laplacians-symbolic-eigenfunctions/O_42.png)