Modele pequenas oscilações em uma molécula de CO
Experimentalmente, uma molécula de CO oscila em torno do seu comprimento de equilíbrio com uma constante efetiva de elasticidade de . As oscilações são governados pela equação de oscilador harmônico quântico. A seguir,
é a massa reduzida de uma molécula,
é a frequência natural,
é o deslocamento da posição de equilíbrio, e
é a constante de Planck reduzida.
![Click for copyable input](assets.pt-br/model-small-oscillations-in-a-co-molecule/In_100.png)
qho = -(\[HBar]^2/(2 m)) Laplacian[u[x], {x}] + (m \[Omega]^2)/
2 x^2 u[x];
Calcule os primeiros quatro valores e funções próprios normalizados.
![Click for copyable input](assets.pt-br/model-small-oscillations-in-a-co-molecule/In_101.png)
sol = DEigensystem[qho, u[x], {x, -\[Infinity], \[Infinity]}, 4,
Assumptions -> \[HBar] > 0 && m > 0 && \[Omega] > 0,
Method -> "Normalize"]
![](assets.pt-br/model-small-oscillations-in-a-co-molecule/O_47.png)
Supondo que a partícula está em uma superposição igual dos quatro estados, a função de onda terá a forma .
![Click for copyable input](assets.pt-br/model-small-oscillations-in-a-co-molecule/In_102.png)
\[Psi][x_, t_] = Total[MapThread[1/2 Exp[I E t #1/\[HBar]] #2 &, sol]]
![](assets.pt-br/model-small-oscillations-in-a-co-molecule/O_48.png)
Calcule os três parâmetros ,
, e
usando unidades de base de unidades de massa atômica, femtossegundos, e picometros, enquanto os valores resultantes estarão perto de unidade de ordem.
![Click for copyable input](assets.pt-br/model-small-oscillations-in-a-co-molecule/In_103.png)
m = QuantityMagnitude[(
Entity["Element", "Carbon"][
EntityProperty["Element", "AtomicMass"]] Entity["Element",
"Oxygen"][EntityProperty["Element", "AtomicMass"]])/(
Entity["Element", "Carbon"][
EntityProperty["Element", "AtomicMass"]] +
Entity["Element", "Oxygen"][
EntityProperty["Element", "AtomicMass"]]), "AtomicMassUnits"]
![](assets.pt-br/model-small-oscillations-in-a-co-molecule/O_49.png)
![Click for copyable input](assets.pt-br/model-small-oscillations-in-a-co-molecule/In_104.png)
\[Omega] =
Sqrt[QuantityMagnitude[Quantity[1.86, "Kilonewtons"/"Meters"],
"AtomicMassUnit"/"Femtoseconds"^2]/m]
![](assets.pt-br/model-small-oscillations-in-a-co-molecule/O_50.png)
![Click for copyable input](assets.pt-br/model-small-oscillations-in-a-co-molecule/In_105.png)
\[HBar] =
QuantityMagnitude[Quantity[1., "ReducedPlanckConstant"],
"AtomicMassUnit"*"Picometers"^2/"Femtoseconds"]
![](assets.pt-br/model-small-oscillations-in-a-co-molecule/O_51.png)
A função densidade de probabilidade do deslocamento é dada por .
![Click for copyable input](assets.pt-br/model-small-oscillations-in-a-co-molecule/In_106.png)
\[Rho][x_, t_] =
FullSimplify[ComplexExpand[Conjugate[\[Psi][x, t]] \[Psi][x, t]]]
![](assets.pt-br/model-small-oscillations-in-a-co-molecule/O_52.png)
Como uma distribuição de probabilidade, a integral de sobre os reais é 1 para todo
.
![Click for copyable input](assets.pt-br/model-small-oscillations-in-a-co-molecule/In_107.png)
Chop[Integrate[\[Rho][x, t], {x, -\[Infinity], \[Infinity]}]]
![](assets.pt-br/model-small-oscillations-in-a-co-molecule/O_53.png)
Visualize a densidade de probabilidade ao longo do tempo.
![](assets.pt-br/model-small-oscillations-in-a-co-molecule/swf_1.png)