미국의 모든 인접 수도 방문하기
미국 본토의 48개 주 주도의 목록을 얻습니다.
In[1]:=
![Click for copyable input](assets.ko/travel-all-capitals-of-the-conterminous-us-states/In_49.png)
capitals =
EntityValue[
EntityClass["AdministrativeDivision", "ContinentalUSStates"],
"CapitalCity"]
Out[1]=
![](assets.ko/travel-all-capitals-of-the-conterminous-us-states/O_38.png)
이러한 GeoPosition 좌표를 다운로드합니다.
In[2]:=
![Click for copyable input](assets.ko/travel-all-capitals-of-the-conterminous-us-states/In_50.png)
GeoPosition[capitals]
Out[2]=
![](assets.ko/travel-all-capitals-of-the-conterminous-us-states/O_39.png)
총 측지 거리가 최소가 되도록 방문 도시의 순서를 계산합니다.
In[3]:=
![Click for copyable input](assets.ko/travel-all-capitals-of-the-conterminous-us-states/In_51.png)
GeoPosition[capitals];
{d, perm} = FindShortestTour[%]
Out[3]=
![](assets.ko/travel-all-capitals-of-the-conterminous-us-states/O_40.png)
경로를 지도에 표시합니다.
In[4]:=
![Click for copyable input](assets.ko/travel-all-capitals-of-the-conterminous-us-states/In_52.png)
GeoGraphics[{GeoPath[capitals[[perm]]], Red, PointSize[Medium],
Point[capitals]}]
Out[4]=
![](assets.ko/travel-all-capitals-of-the-conterminous-us-states/O_41.png)
같은 도시를 같은 순서로 운전할 수 있도록 운전 경로를 계산합니다.
In[5]:=
![Click for copyable input](assets.ko/travel-all-capitals-of-the-conterminous-us-states/In_53.png)
td = TravelDirections[capitals[[perm]]];
지도에 해당 경로를 나타냅니다.
In[6]:=
![Click for copyable input](assets.ko/travel-all-capitals-of-the-conterminous-us-states/In_54.png)
GeoGraphics[{td["TravelPath"], Red, PointSize[Medium],
Point[capitals]}]
Out[6]=
![](assets.ko/travel-all-capitals-of-the-conterminous-us-states/O_42.png)
운전 총 거리를 알아봅니다.
In[7]:=
![Click for copyable input](assets.ko/travel-all-capitals-of-the-conterminous-us-states/In_55.png)
td["TravelDistance"]
Out[7]=
![](assets.ko/travel-all-capitals-of-the-conterminous-us-states/O_43.png)
측지 거리와 비교합니다.
In[8]:=
![Click for copyable input](assets.ko/travel-all-capitals-of-the-conterminous-us-states/In_56.png)
d
Out[8]=
![](assets.ko/travel-all-capitals-of-the-conterminous-us-states/O_44.png)