Connectivité des comtés américains
Construisez le graphe de connectivité entre les comtés américains voisins.
Prenez la liste de tous les comtés dans les États continentaux contigus.
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_28.png)
Length[counties =
Flatten[EntityClass["AdministrativeDivision",
"ContinentalUSStates"]["Subdivisions"]]]
![](assets.fr/connectivity-of-us-counties/O_26.png)
Ajoutez le district de Columbia qui n'est pas une subdivision de l'un des 48 états contigus.
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_29.png)
AppendTo[counties,
Entity["AdministrativeDivision", {"DistrictOfColumbia",
"DistrictOfColumbia", "UnitedStates"}]];
Calculez la liste des comtés limitrophes de chaque comté.
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_30.png)
bordering = EntityValue[counties, "BorderingCounties"];
Rejetez certains cas pour lesquels des informations limitrophes ne sont pas disponibles.
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_31.png)
Length[missingpos = Position[bordering, _Missing]]
![](assets.fr/connectivity-of-us-counties/O_27.png)
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_32.png)
counties = Delete[counties, missingpos];
bordering = Delete[bordering, missingpos];
Construisez les arêtes du graphe de connectivité des comtés américains
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_33.png)
Length[edges =
DeleteDuplicates[
Sort /@ Flatten[
MapThread[Thread[UndirectedEdge[##]] &, {counties, bordering}]]]]
![](assets.fr/connectivity-of-us-counties/O_28.png)
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_34.png)
Graph[counties, edges]
![](assets.fr/connectivity-of-us-counties/O_29.png)
Pour construire une représentation plus familière, téléchargez la position centrale de tous les comtés.
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_35.png)
pos = GeoPosition[EntityValue[counties, "Position"]]
![](assets.fr/connectivity-of-us-counties/O_30.png)
Utilisez la projection cartographique suivante.
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_36.png)
proj = {"LambertAzimuthal",
"Centering" ->
Entity["City", {"Topeka", "Kansas", "UnitedStates"}]};
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_37.png)
projpos = First@GeoGridPosition[pos, proj];
On obtient alors l'intégration de graphe suivante.
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_38.png)
graph = Graph[counties, edges, VertexCoordinates -> projpos]
![](assets.fr/connectivity-of-us-counties/O_31.png)
Pour aller du comté de San Francisco à Manhattan, il faut visiter au moins 67 comtés, y compris le premier et le dernier.
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_39.png)
Length[path = FindShortestPath[graph,
Entity[
"AdministrativeDivision", {"SanFranciscoCounty", "California",
"UnitedStates"}],
Entity[
"AdministrativeDivision", {"NewYorkCounty", "NewYork",
"UnitedStates"}]]]
![](assets.fr/connectivity-of-us-counties/O_32.png)
![Click for copyable input](assets.fr/connectivity-of-us-counties/In_40.png)
HighlightGraph[graph, PathGraph[path]]
![](assets.fr/connectivity-of-us-counties/O_33.png)