美国各郡间的连通性
构建美国各郡间的连通图.
提取美国大陆相连的州的所有郡的列表.
In[1]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_28.png)
Length[counties =
Flatten[EntityClass["AdministrativeDivision",
"ContinentalUSStates"]["Subdivisions"]]]
Out[1]=
![](assets.zh/connectivity-of-us-counties/O_26.png)
加上不属于 48 个相连本土州的哥伦比亚特区.
In[2]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_29.png)
AppendTo[counties,
Entity["AdministrativeDivision", {"DistrictOfColumbia",
"DistrictOfColumbia", "UnitedStates"}]];
计算与每个郡边界相连的郡的列表.
In[3]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_30.png)
bordering = EntityValue[counties, "BorderingCounties"];
除去无法获取边界信息的郡.
In[4]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_31.png)
Length[missingpos = Position[bordering, _Missing]]
Out[4]=
![](assets.zh/connectivity-of-us-counties/O_27.png)
In[5]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_32.png)
counties = Delete[counties, missingpos];
bordering = Delete[bordering, missingpos];
构建美国各郡的连通图.
In[6]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_33.png)
Length[edges =
DeleteDuplicates[
Sort /@ Flatten[
MapThread[Thread[UndirectedEdge[##]] &, {counties, bordering}]]]]
Out[6]=
![](assets.zh/connectivity-of-us-counties/O_28.png)
In[7]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_34.png)
Graph[counties, edges]
Out[7]=
![](assets.zh/connectivity-of-us-counties/O_29.png)
为构建更常见的嵌入图,下载所有郡的中心位置.
In[8]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_35.png)
pos = GeoPosition[EntityValue[counties, "Position"]]
Out[8]=
![](assets.zh/connectivity-of-us-counties/O_30.png)
使用以下地图投影.
In[9]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_36.png)
proj = {"LambertAzimuthal",
"Centering" ->
Entity["City", {"Topeka", "Kansas", "UnitedStates"}]};
In[10]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_37.png)
projpos = First@GeoGridPosition[pos, proj];
现在有以下嵌入图.
In[11]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_38.png)
graph = Graph[counties, edges, VertexCoordinates -> projpos]
Out[11]=
![](assets.zh/connectivity-of-us-counties/O_31.png)
从旧金山郡到曼哈顿,你需要访问最少 67 个郡,包括起点和终点.
In[12]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_39.png)
Length[path = FindShortestPath[graph,
Entity[
"AdministrativeDivision", {"SanFranciscoCounty", "California",
"UnitedStates"}],
Entity[
"AdministrativeDivision", {"NewYorkCounty", "NewYork",
"UnitedStates"}]]]
Out[12]=
![](assets.zh/connectivity-of-us-counties/O_32.png)
In[13]:=
![Click for copyable input](assets.zh/connectivity-of-us-counties/In_40.png)
HighlightGraph[graph, PathGraph[path]]
Out[13]=
![](assets.zh/connectivity-of-us-counties/O_33.png)