Conectividade dos municípios dos EUA
Construa o gráfico de conectividade entre municípios vizinhos dos Estados Unidos.
Pegue a lista de todos os municípios dos estados contíguos dos Estados Unidos.
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_28.png)
Length[counties =
Flatten[EntityClass["AdministrativeDivision",
"ContinentalUSStates"]["Subdivisions"]]]
![](assets.pt-br/connectivity-of-us-counties/O_26.png)
Adicione o Distrito de Columbia, que não é uma subdivisão de nenhum dos 48 estados contíguos.
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_29.png)
AppendTo[counties,
Entity["AdministrativeDivision", {"DistrictOfColumbia",
"DistrictOfColumbia", "UnitedStates"}]];
Calcule a lista de municípios que fazem fronteira com cada município.
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_30.png)
bordering = EntityValue[counties, "BorderingCounties"];
Descarte alguns casos para os quais a informação de limite não está disponível.
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_31.png)
Length[missingpos = Position[bordering, _Missing]]
![](assets.pt-br/connectivity-of-us-counties/O_27.png)
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_32.png)
counties = Delete[counties, missingpos];
bordering = Delete[bordering, missingpos];
Construa as bordas do gráfico de conectividade dos municípios dos Estados Unidos.
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_33.png)
Length[edges =
DeleteDuplicates[
Sort /@ Flatten[
MapThread[Thread[UndirectedEdge[##]] &, {counties, bordering}]]]]
![](assets.pt-br/connectivity-of-us-counties/O_28.png)
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_34.png)
Graph[counties, edges]
![](assets.pt-br/connectivity-of-us-counties/O_29.png)
Para construir uma incorporação mais familiar, faça download da posição central de todos os municípios.
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_35.png)
pos = GeoPosition[EntityValue[counties, "Position"]]
![](assets.pt-br/connectivity-of-us-counties/O_30.png)
Use a seguinte projeção cartográfica.
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_36.png)
proj = {"LambertAzimuthal",
"Centering" ->
Entity["City", {"Topeka", "Kansas", "UnitedStates"}]};
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_37.png)
projpos = First@GeoGridPosition[pos, proj];
Assim você tem a seguinte incorporação de gráfico.
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_38.png)
graph = Graph[counties, edges, VertexCoordinates -> projpos]
![](assets.pt-br/connectivity-of-us-counties/O_31.png)
Para ir de San Francisco para Manhattan, você precisa visitar pelo menos 67 municípios, incluindo o inicial e o final.
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_39.png)
Length[path = FindShortestPath[graph,
Entity[
"AdministrativeDivision", {"SanFranciscoCounty", "California",
"UnitedStates"}],
Entity[
"AdministrativeDivision", {"NewYorkCounty", "NewYork",
"UnitedStates"}]]]
![](assets.pt-br/connectivity-of-us-counties/O_32.png)
![Click for copyable input](assets.pt-br/connectivity-of-us-counties/In_40.png)
HighlightGraph[graph, PathGraph[path]]
![](assets.pt-br/connectivity-of-us-counties/O_33.png)