Visualize and Analyze Anatomical Structures: New in Wolfram Language 11

Visualize and Analyze Anatomical Structures

Plot the bone structure and skin of the human foot and estimate its surface area (in square millimeters).

In[1]:=

Row[EntityValue[{Entity["AnatomicalStructure", "RightFoot"], 
   Entity["AnatomicalStructure", "SkinOfRightFoot"]}, "MeshRegion"]]

Out[1]=

In[2]:=

Area[EntityValue[Entity["AnatomicalStructure", "SkinOfRightFoot"], 
  "MeshRegion"]]

Out[2]=

Plot the connectivity of the distal branches of the brachial artery.

In[3]:=

NestGraph[Cases[EntityValue[#, "Branches"], _Entity] &, 
 Entity["AnatomicalStructure", "BrachialArtery"], 3, 
 VertexLabels -> Placed["Name", Tooltip], EdgeStyle -> Pink, 
 VertexStyle -> Pink, GraphStyle -> "BasicBlack"]

Out[3]=

Find the parts of the left forearm.

In[4]:=

g = NestGraph[Cases[EntityValue[#, "ConstitutionalParts"], _Entity] &,
   Entity["AnatomicalStructure", "LeftForearm"], 2]

Out[4]=

Compute the combined length of pharynx, esophagus, stomach, small intestine, and large intestine.

In[5]:=

UnitConvert[
 EntityValue[
  EntityGroup[{Entity["AnatomicalStructure", "Pharynx"], 
    Entity["AnatomicalStructure", "Esophagus"], 
    Entity["AnatomicalStructure", "Stomach"], 
    Entity["AnatomicalStructure", "SmallIntestine"], 
    Entity["AnatomicalStructure", "LargeIntestine"]}], 
  "Length"], "Metric"]

Out[5]=

Compare length and width of the foot in men and women.

In[6]:=

# -> (UnitConvert[#, "Centimeters"] & /@ 
     EntityValue[
      EntityInstance[Entity["AnatomicalStructure", "Foot"], 
       "Gender" -> #], {"Length", "Width"}, 
      "PropertyAssociation"]) & /@ {"Female", "Male"}

Out[6]=

Wolfram Language™

Visualize and Analyze Anatomical Structures

Related Examples