Observez une particule quantique dans une boîte
Une particule quantique libre de se déplacer à l'intérieur d'un rectangle bidimensionnel dont les côtés sont et
est décrite par l'équation de Schrödinger bidimensionnelle dépendant du temps, ainsi que par des conditions aux limites qui forcent la fonction d'onde à s'annuler à la frontière.
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_92.png)
eqn = I D[\[Psi][x, y, t], t] == -\[HBar]^2/(2 m)
Laplacian[\[Psi][x, y, t], {x, y}];
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_93.png)
bcs = {\[Psi][0, y, t] == 0, \[Psi][xMax, y, t] ==
0, \[Psi][x, yMax, t] == 0, \[Psi][x, 0, t] == 0};
Cette équation a une solution générale qui est une somme infinie formelle de ce qu'on appelle les états propres.
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_94.png)
DSolveValue[{eqn, bcs}, \[Psi][x, y, t], {x, y, t}]
![](assets.fr/observe-a-quantum-particle-in-a-box/O_43.png)
Définissez une condition initiale égale à un état propre.
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_95.png)
initEigen = \[Psi][x, y, 0] ==
2 /Sqrt[xMax yMax] Sin[(\[Pi] x)/xMax] Sin[(\[Pi] y)/yMax];
Dans ce cas, la solution est simplement un multiple dépendant du temps (de module unitaire) de la condition initiale.
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_96.png)
DSolveValue[{eqn, bcs, initEigen}, \[Psi][x, y, t], {x, y, t}]
![](assets.fr/observe-a-quantum-particle-in-a-box/O_44.png)
Définissez une condition initiale qui est une somme d'états propres. Comme les conditions initiales ne sont pas un état propre, la densité de probabilité de l'emplacement de la particule dépendra du temps.
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_97.png)
initSum = \[Psi][x, y, 0] ==
Sqrt[2]/Sqrt[
xMax yMax] (Sin[(2 \[Pi] x)/xMax] Sin[(\[Pi] y)/yMax] +
Sin[(\[Pi] x)/xMax] Sin[(3 \[Pi] y)/yMax]);
Résolvez-la avec la nouvelle condition initiale.
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_98.png)
sol = DSolveValue[{eqn, bcs, initSum}, \[Psi][x, y, t], {x, y, t}]
![](assets.fr/observe-a-quantum-particle-in-a-box/O_45.png)
Calculez la densité de probabilité en insérant les valeurs de la constante de Planck réduite, de la masse des électrons et d'une boîte de taille atomique, en utilisant les unités de masse des électrons, les nanomètres et les femtosecondes.
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_99.png)
\[HBar] =
QuantityMagnitude[Quantity[1., "ReducedPlanckConstant"],
"ElectronMass" * ("Nanometers")^2/"Femtoseconds"]
![](assets.fr/observe-a-quantum-particle-in-a-box/O_46.png)
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_100.png)
\[Rho][x_, y_, t_] =
FullSimplify[ComplexExpand[Conjugate[sol] sol]] /. {m -> 1,
xMax -> 1, yMax -> 1}
![](assets.fr/observe-a-quantum-particle-in-a-box/O_47.png)
Visualisez la densité de probabilité à l'intérieur de la boîte dans le temps.
![Click for copyable input](assets.fr/observe-a-quantum-particle-in-a-box/In_101.png)
ListAnimate[
Table[Plot3D[\[Rho][x , y , t], {x, 0, 1}, {y, 0, 1},
PlotTheme -> {"Scientific", "SolidGrid"}, AxesLabel -> {"\!\(\*
StyleBox[\"x\", \"SO\"]\) (nm)", " \!\(\*
StyleBox[\"y\", \"SO\"]\) (nm)", "\!\(\*
StyleBox[\"\[Rho]\", \"SO\"]\) (\!\(\*SuperscriptBox[\(nm\), \
\(-2\)]\))"}, ImageSize -> Medium, PlotRange -> {0, 7}], {t, 0,
19, .5}]]
![](assets.fr/observe-a-quantum-particle-in-a-box/swf_6.png)