Modélisez une chaîne pendante
Trouvez la position avec l'énergie potentielle minimale d'une chaîne ou d'un fil de longueur suspendue entre deux points.
![](assets.fr/model-a-hanging-chain/O_41.png)
Configurez les valeurs de paramètre de la longueur de la chaîne , la hauteur de l'extrémité gauche
et la hauteur de l'extrémité droite
.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_73.png)
L = 4; a = 1; b = 3;
Soit , la hauteur de la chaîne comme fonction de position horizontale, avec
.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_74.png)
xf = 1; nh = 201; h := xf/nh;
Configurez les variables pour la hauteur de la chaîne .
![Click for copyable input](assets.fr/model-a-hanging-chain/In_75.png)
varsy = Array[y, nh + 1, {0, nh}];
Désignez la pente à la position par
et configurez-lui des variables.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_76.png)
varsm = Array[m, nh + 1, {0, nh}];
Désignez l'énergie potentielle partielle de à
par
.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_77.png)
varsv = Array[v, nh + 1, {0, nh}];
Désignez la longueur de la chaîne à la position par
et configurez-lui des variables.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_78.png)
varss = Array[s, nh + 1, {0, nh}];
Joignez toutes les variables.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_79.png)
vars = Join[varsm, varsy, varsv, varss];
L'objectif est de minimiser l'énergie potentielle totale .
![Click for copyable input](assets.fr/model-a-hanging-chain/In_80.png)
objfn = v[nh];
Voici la valeur limite des contraintes géométriques.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_81.png)
bndcons = {y[0] == a, y[nh] == b, v[0] == 0, s[0] == 0, s[nh] == L};
Discrétisez les EDO : ,
,
.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_82.png)
odecons = {Table[
y[j + 1] == y[j] + 0.5*h*(m[j] + m[j + 1]), {j, 0, nh - 1}],
Table[v[j + 1] ==
v[j] + 0.5*
h*(y[j]*Sqrt[1 + m[j]^2] + y[j + 1]*Sqrt[1 + m[j + 1]^2]), {j,
0, nh - 1}],
Table[s[j + 1] ==
s[j] + 0.5*h*(Sqrt[1 + m[j]^2] + Sqrt[1 + m[j + 1]^2]), {j, 0,
nh - 1}]};
Choisissez des points initiaux pour les variables.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_83.png)
tmin = If[b > a, 0.25 , 0.75]; init =
Join[Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}],
Table[4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a, {k, 0, nh}],
Table[(4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a)*4*
Abs[b - a]*((k/nh) - tmin), {k, 0, nh}],
Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}]];
Minimisez l'énergie potentielle totale, sous réserve des contraintes.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_84.png)
sol = FindMinimum[{objfn, Join[bndcons, odecons]},
Thread[{vars, init}]];
Extrayez les points de solution.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_85.png)
solpts = Table[{i h, y[i] /. sol[[2]]}, {i, 0, nh}];
Tracez la position de la chaîne avec un minimum d'énergie potentielle.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_86.png)
ListPlot[solpts, ImageSize -> Medium, PlotTheme -> "Marketing"]
![](assets.fr/model-a-hanging-chain/O_42.png)
Utilisez FindFit pour adapter le résultat à la courbe caténaire.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_87.png)
catenary[t_] = c1 + (1/c2) Cosh[c2 (t - c3)];
![Click for copyable input](assets.fr/model-a-hanging-chain/In_88.png)
fitsol = FindFit[solpts, catenary[t], {c1, c2, c3}, {t}]
![](assets.fr/model-a-hanging-chain/O_43.png)
Tracez les points de solution avec la courbe caténaire.
![Click for copyable input](assets.fr/model-a-hanging-chain/In_89.png)
Show[Plot[catenary[t] /. fitsol, {t, 0, 1},
PlotStyle -> Directive[Green, Thickness[0.01]],
ImageSize -> Medium],
ListPlot[Take[solpts, 1 ;; nh ;; 5], PlotStyle -> PointSize[.02]]]
![](assets.fr/model-a-hanging-chain/O_44.png)