Создание модели подвесной цепи
Найти положение с минимальной потенциальной энергией цепи или кабеля длины , провесающей между двумя точками.
![](assets.ru/model-a-hanging-chain/O_41.png)
Задать значения параметров для длины цепи , высоты левого конца
, и высоты правого конца
.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_73.png)
L = 4; a = 1; b = 3;
Допустим, что является высотой цепи в функции горизонтальной позиции с
.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_74.png)
xf = 1; nh = 201; h := xf/nh;
Задать переменные для высоты цепи .
![Click for copyable input](assets.ru/model-a-hanging-chain/In_75.png)
varsy = Array[y, nh + 1, {0, nh}];
Указать уклон в положении через
и задать его величину.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_76.png)
varsm = Array[m, nh + 1, {0, nh}];
Указать частичную потенциальную энергию от до
через
.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_77.png)
varsv = Array[v, nh + 1, {0, nh}];
Указать длину цепи в положении через
и задать её величинy.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_78.png)
varss = Array[s, nh + 1, {0, nh}];
Объединить все величины.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_79.png)
vars = Join[varsm, varsy, varsv, varss];
Цель данного шага - минимизировать общую потенциальную энергию .
![Click for copyable input](assets.ru/model-a-hanging-chain/In_80.png)
objfn = v[nh];
Ниже представлены ограничения предельных значений, основанные на геометрическом строении.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_81.png)
bndcons = {y[0] == a, y[nh] == b, v[0] == 0, s[0] == 0, s[nh] == L};
Дискретизировать обыкновенные дифференциальные уравнения: ,
,
.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_82.png)
odecons = {Table[
y[j + 1] == y[j] + 0.5*h*(m[j] + m[j + 1]), {j, 0, nh - 1}],
Table[v[j + 1] ==
v[j] + 0.5*
h*(y[j]*Sqrt[1 + m[j]^2] + y[j + 1]*Sqrt[1 + m[j + 1]^2]), {j,
0, nh - 1}],
Table[s[j + 1] ==
s[j] + 0.5*h*(Sqrt[1 + m[j]^2] + Sqrt[1 + m[j + 1]^2]), {j, 0,
nh - 1}]};
Выберать начальные точки для величин.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_83.png)
tmin = If[b > a, 0.25 , 0.75]; init =
Join[Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}],
Table[4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a, {k, 0, nh}],
Table[(4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a)*4*
Abs[b - a]*((k/nh) - tmin), {k, 0, nh}],
Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}]];
Минимизировать общую потенциальную энергию, основываясь на ограничениях.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_84.png)
sol = FindMinimum[{objfn, Join[bndcons, odecons]},
Thread[{vars, init}]];
Извлечь точки решения.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_85.png)
solpts = Table[{i h, y[i] /. sol[[2]]}, {i, 0, nh}];
Графически изобразить положение цепи с минимальной потенциальной энергией.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_86.png)
ListPlot[solpts, ImageSize -> Medium, PlotTheme -> "Marketing"]
![](assets.ru/model-a-hanging-chain/O_42.png)
Используйте FindFit для подгонки результата до цепной линии.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_87.png)
catenary[t_] = c1 + (1/c2) Cosh[c2 (t - c3)];
![Click for copyable input](assets.ru/model-a-hanging-chain/In_88.png)
fitsol = FindFit[solpts, catenary[t], {c1, c2, c3}, {t}]
![](assets.ru/model-a-hanging-chain/O_43.png)
Графически изобразите точки решения вместе с цепной линией.
![Click for copyable input](assets.ru/model-a-hanging-chain/In_89.png)
Show[Plot[catenary[t] /. fitsol, {t, 0, 1},
PlotStyle -> Directive[Green, Thickness[0.01]],
ImageSize -> Medium],
ListPlot[Take[solpts, 1 ;; nh ;; 5], PlotStyle -> PointSize[.02]]]
![](assets.ru/model-a-hanging-chain/O_44.png)