Solución de un problema de valor de límite usando la función de Green
Resuelva la siguiente ecuación diferencial de segundo orden sujeta a condiciones de límite homogéneas.
In[1]:=
![Click for copyable input](assets.es/solve-a-boundary-value-problem-using-a-greens-func/In_119.png)
eqn = -u''[x] - u'[x] + 6 u[x] == f[x];
In[2]:=
![Click for copyable input](assets.es/solve-a-boundary-value-problem-using-a-greens-func/In_120.png)
bc0 = u[0] == 0;
In[3]:=
![Click for copyable input](assets.es/solve-a-boundary-value-problem-using-a-greens-func/In_121.png)
bc1 = u[1] == 0;
El término de fuerza es dado por la siguiente función f[x].
In[4]:=
![Click for copyable input](assets.es/solve-a-boundary-value-problem-using-a-greens-func/In_122.png)
f[x_] := E^(-a x)
Calcule la función de Green para el operador diferencial correspondiente.
In[5]:=
![Click for copyable input](assets.es/solve-a-boundary-value-problem-using-a-greens-func/In_123.png)
gf[y_, x_] = GreenFunction[{eqn[[1]], bc0, bc1}, u[x], {x, 0, 1}, y]
Out[5]=
![](assets.es/solve-a-boundary-value-problem-using-a-greens-func/O_65.png)
Represente gráficamente la función de Green para distintos valores de que yacen entre 0 y 1.
In[6]:=
![Click for copyable input](assets.es/solve-a-boundary-value-problem-using-a-greens-func/In_124.png)
Plot[Table[gf[y, x], {y, 0, 1, 0.2}] // Evaluate, {x, 0, 1}]
Out[6]=
![](assets.es/solve-a-boundary-value-problem-using-a-greens-func/O_66.png)
La solución de la ecuación diferencial original con el término de fuerza dado puede ahora ser calculado usando la integral de convolución en el intervalo .
In[7]:=
![Click for copyable input](assets.es/solve-a-boundary-value-problem-using-a-greens-func/In_125.png)
sol = Integrate[gf[y, x] f[y], {y, 0, 1}, Assumptions -> 0 < x < 1] //
Simplify
Out[7]=
![](assets.es/solve-a-boundary-value-problem-using-a-greens-func/O_67.png)
Represente gráficamente la solución para distintos valores del parámetro .
In[8]:=
![Click for copyable input](assets.es/solve-a-boundary-value-problem-using-a-greens-func/In_126.png)
Plot[Table[sol, {a, {1/4, 1, 2, 4}}] // Evaluate, {x, 0, 1}]
Out[8]=
![](assets.es/solve-a-boundary-value-problem-using-a-greens-func/O_68.png)