Modelado de una cadena colgante
Encuentre la posición con energía potencial mínima de una cadena o cable de longitud suspendida entre dos puntos.
![](assets.es/model-a-hanging-chain/O_41.png)
Configure los valores de parámetro para la longitud de la cadena , la altura del extremo izquierdo
, y la altura del extremo derecho
.
![Click for copyable input](assets.es/model-a-hanging-chain/In_73.png)
L = 4; a = 1; b = 3;
Permita que sea la altura de la cadena como una función de posición horizontal, con
.
![Click for copyable input](assets.es/model-a-hanging-chain/In_74.png)
xf = 1; nh = 201; h := xf/nh;
Configure las variables para la altura de la cadena .
![Click for copyable input](assets.es/model-a-hanging-chain/In_75.png)
varsy = Array[y, nh + 1, {0, nh}];
Denote la pendiente en posición por
y configure las variables para ésta.
![Click for copyable input](assets.es/model-a-hanging-chain/In_76.png)
varsm = Array[m, nh + 1, {0, nh}];
Denote la energía potencial parcial de a
por
.
![Click for copyable input](assets.es/model-a-hanging-chain/In_77.png)
varsv = Array[v, nh + 1, {0, nh}];
Denote la longitud de la cadena en posición por
y configure las variables para ésta.
![Click for copyable input](assets.es/model-a-hanging-chain/In_78.png)
varss = Array[s, nh + 1, {0, nh}];
Junte todas las variables.
![Click for copyable input](assets.es/model-a-hanging-chain/In_79.png)
vars = Join[varsm, varsy, varsv, varss];
El objetivo es minimizar la energía potencial total .
![Click for copyable input](assets.es/model-a-hanging-chain/In_80.png)
objfn = v[nh];
Aquí hay restricciones de valores de límite desde la geometría.
![Click for copyable input](assets.es/model-a-hanging-chain/In_81.png)
bndcons = {y[0] == a, y[nh] == b, v[0] == 0, s[0] == 0, s[nh] == L};
Discretice las ecuaciones diferenciales ordinarias: ,
,
.
![Click for copyable input](assets.es/model-a-hanging-chain/In_82.png)
odecons = {Table[
y[j + 1] == y[j] + 0.5*h*(m[j] + m[j + 1]), {j, 0, nh - 1}],
Table[v[j + 1] ==
v[j] + 0.5*
h*(y[j]*Sqrt[1 + m[j]^2] + y[j + 1]*Sqrt[1 + m[j + 1]^2]), {j,
0, nh - 1}],
Table[s[j + 1] ==
s[j] + 0.5*h*(Sqrt[1 + m[j]^2] + Sqrt[1 + m[j + 1]^2]), {j, 0,
nh - 1}]};
Seleccione puntos iniciales para las variables.
![Click for copyable input](assets.es/model-a-hanging-chain/In_83.png)
tmin = If[b > a, 0.25 , 0.75]; init =
Join[Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}],
Table[4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a, {k, 0, nh}],
Table[(4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a)*4*
Abs[b - a]*((k/nh) - tmin), {k, 0, nh}],
Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}]];
Minimice la energía potencial total, sujeta a las restricciones.
![Click for copyable input](assets.es/model-a-hanging-chain/In_84.png)
sol = FindMinimum[{objfn, Join[bndcons, odecons]},
Thread[{vars, init}]];
Extraiga los puntos de solución.
![Click for copyable input](assets.es/model-a-hanging-chain/In_85.png)
solpts = Table[{i h, y[i] /. sol[[2]]}, {i, 0, nh}];
Represente gráficamente la posición de la cadena con energía potencial mínima.
![Click for copyable input](assets.es/model-a-hanging-chain/In_86.png)
ListPlot[solpts, ImageSize -> Medium, PlotTheme -> "Marketing"]
![](assets.es/model-a-hanging-chain/O_42.png)
Utilice FindFit para ajustar el resultado a la curva catenaria.
![Click for copyable input](assets.es/model-a-hanging-chain/In_87.png)
catenary[t_] = c1 + (1/c2) Cosh[c2 (t - c3)];
![Click for copyable input](assets.es/model-a-hanging-chain/In_88.png)
fitsol = FindFit[solpts, catenary[t], {c1, c2, c3}, {t}]
![](assets.es/model-a-hanging-chain/O_43.png)
Represente gráficamente los puntos de solución junto con la curva catenaria.
![Click for copyable input](assets.es/model-a-hanging-chain/In_89.png)
Show[Plot[catenary[t] /. fitsol, {t, 0, 1},
PlotStyle -> Directive[Green, Thickness[0.01]],
ImageSize -> Medium],
ListPlot[Take[solpts, 1 ;; nh ;; 5], PlotStyle -> PointSize[.02]]]
![](assets.es/model-a-hanging-chain/O_44.png)