Calcule integrales definidas usando reducción G
La expresión de funciones en términos de MeijerG permite el cálculo de su producto sobre reales positivos.
Cree una regla para expresar el integral de un producto de funciones en términos de funciones de MeijerG.
In[1]:=
![Click for copyable input](assets.es/compute-definite-integrals-using-g-reduction/In_145.png)
IntegrateMeijerG[f_ g_, {z_, 0, Infinity}] /; FreeQ[{f, g}, MeijerG] :=
IntegrateMeijerG[
MeijerGReduce[f, z] MeijerGReduce[g, z], {z, 0, Infinity}]
Esta integral puede ser expresada exactamente en términos de una única expresión de MeijerG.
In[2]:=
![Click for copyable input](assets.es/compute-definite-integrals-using-g-reduction/In_146.png)
IntegrateMeijerG[\[Alpha]_ Inactive[MeijerG][{a_, b_}, {c_,
d_}, \[Omega]_. z_] Inactive[MeijerG][{e_, f_}, {g_,
h_}, \[Eta]_. z_], {z_, 0, Infinity}] /;
FreeQ[{\[Alpha], \[Omega], \[Eta]},
z] := \[Alpha] MeijerG[{Join[-c, e], Join[f, d]}, {Join[-a, g],
Join[h, -b]}, \[Eta]/\[Omega]]
Aplique el esquema para evaluar .
In[3]:=
![Click for copyable input](assets.es/compute-definite-integrals-using-g-reduction/In_147.png)
Plot[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, 10}, Filling -> Axis,
PlotRange -> All]
Out[3]=
![](assets.es/compute-definite-integrals-using-g-reduction/O_81.png)
In[4]:=
![Click for copyable input](assets.es/compute-definite-integrals-using-g-reduction/In_148.png)
IntegrateMeijerG[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}]
Out[4]=
![](assets.es/compute-definite-integrals-using-g-reduction/O_82.png)
Obtenga el mismo resultado usando Integrate.
In[5]:=
![Click for copyable input](assets.es/compute-definite-integrals-using-g-reduction/In_149.png)
Integrate[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}]
Out[5]=
![](assets.es/compute-definite-integrals-using-g-reduction/O_83.png)
A pesar de que la respuesta se ve muy diferente, ésta es equivalente.
In[6]:=
![Click for copyable input](assets.es/compute-definite-integrals-using-g-reduction/In_150.png)
IntegrateMeijerG[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}];
Integrate[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}];
FullSimplify[% == %%]
Out[6]=
![](assets.es/compute-definite-integrals-using-g-reduction/O_84.png)