Projiziertes Raster von Längengrad- und Breitengradlinien
Diese Funktion zeichnet das vollständige Gitternetz von Breitenkreislinien und Meridianen (jeweils in rot und blau) unter Verwendung einer Kartenprojektion.
In[1]:=
![Click for copyable input](assets.de/projected-grid-of-latitude-and-longitude-lines/In_29.png)
graticule[proj_] :=
With[{centering = {0, 0, 1.5},
diff = Quantity[10, "AngularDegrees"]},
Framed[Labeled[
GeoGraphics[GeoRange -> "World",
GeoProjection -> {proj, "Centering" -> centering},
GeoGridLines -> diff, GeoGridLinesStyle -> {Red, Blue},
GeoBackground -> None, PlotRangePadding -> Scaled[0.1]], proj]]
]
Hier sind drei Beispiele.
In[2]:=
![Click for copyable input](assets.de/projected-grid-of-latitude-and-longitude-lines/In_30.png)
graticule["Armadillo"]
Out[2]=
![](assets.de/projected-grid-of-latitude-and-longitude-lines/O_18.png)
In[3]:=
![Click for copyable input](assets.de/projected-grid-of-latitude-and-longitude-lines/In_31.png)
graticule["AmericanPolyconic"]
Out[3]=
![](assets.de/projected-grid-of-latitude-and-longitude-lines/O_19.png)
In[4]:=
![Click for copyable input](assets.de/projected-grid-of-latitude-and-longitude-lines/In_32.png)
graticule["Bonne"]
Out[4]=
![](assets.de/projected-grid-of-latitude-and-longitude-lines/O_20.png)
Berechnen Sie die Längengrad- und Breitengradliniennetze für alle 151 Projektionen mit einem kugelförmigen Bezugsmodell.
In[5]:=
![Click for copyable input](assets.de/projected-grid-of-latitude-and-longitude-lines/In_33.png)
plots = graticule /@ GeoProjectionData["Spherical"];
Rastern Sie diese mit einer Bildgröße, die klein genug ist.
In[6]:=
![Click for copyable input](assets.de/projected-grid-of-latitude-and-longitude-lines/In_34.png)
images = Rasterize[#, ImageSize -> 200] & /@ plots;
Erstellen Sie eine Bildcollage.
In[7]:=
![Click for copyable input](assets.de/projected-grid-of-latitude-and-longitude-lines/In_35.png)
ImageCollage[images]
Out[7]=
![](assets.de/projected-grid-of-latitude-and-longitude-lines/O_21.png)