Rejilla proyectada de líneas de latitud y longitud
Esta función traza la rejilla completa de paralelos y meridianos (en rojo y azul, respectivamente) luego de ser proyectadas con una proyección geográfica.
In[1]:=
![Click for copyable input](assets.es/projected-grid-of-latitude-and-longitude-lines/In_29.png)
graticule[proj_] :=
With[{centering = {0, 0, 1.5},
diff = Quantity[10, "AngularDegrees"]},
Framed[Labeled[
GeoGraphics[GeoRange -> "World",
GeoProjection -> {proj, "Centering" -> centering},
GeoGridLines -> diff, GeoGridLinesStyle -> {Red, Blue},
GeoBackground -> None, PlotRangePadding -> Scaled[0.1]], proj]]
]
Éstos son tres ejemplos.
In[2]:=
![Click for copyable input](assets.es/projected-grid-of-latitude-and-longitude-lines/In_30.png)
graticule["Armadillo"]
Out[2]=
![](assets.es/projected-grid-of-latitude-and-longitude-lines/O_19.png)
In[3]:=
![Click for copyable input](assets.es/projected-grid-of-latitude-and-longitude-lines/In_31.png)
graticule["AmericanPolyconic"]
Out[3]=
![](assets.es/projected-grid-of-latitude-and-longitude-lines/O_20.png)
In[4]:=
![Click for copyable input](assets.es/projected-grid-of-latitude-and-longitude-lines/In_32.png)
graticule["Bonne"]
Out[4]=
![](assets.es/projected-grid-of-latitude-and-longitude-lines/O_21.png)
Calcule la rejilla de latitud-longitud para todas las 151 proyecciones con un modelo esférico de referencia.
In[5]:=
![Click for copyable input](assets.es/projected-grid-of-latitude-and-longitude-lines/In_33.png)
plots = graticule /@ GeoProjectionData["Spherical"];
Rasterícelos usando tamaño de imagen lo suficientemente pequeño.
In[6]:=
![Click for copyable input](assets.es/projected-grid-of-latitude-and-longitude-lines/In_34.png)
images = Rasterize[#, ImageSize -> 200] & /@ plots;
Construya un collage de imágenes.
In[7]:=
![Click for copyable input](assets.es/projected-grid-of-latitude-and-longitude-lines/In_35.png)
ImageCollage[images]
Out[7]=
![](assets.es/projected-grid-of-latitude-and-longitude-lines/O_22.png)