Distribuição de Marchenko–Pastur
A distribuição de Marchenko–Pastur é a distribuição de limite de valores próprios de matrizes de Wishart como a matriz de dimensão e graus de liberdade
ambos tendem ao infinito com relação
. Para
, a distribuição não tem massa pontual e a função densidade de probabilidade está bem definida.
![Click for copyable input](assets.pt-br/marchenko-pastur-distribution/In_70.png)
PDF[MarchenkoPasturDistribution[1/2], x]
![](assets.pt-br/marchenko-pastur-distribution/O_31.png)
![](assets.pt-br/marchenko-pastur-distribution/O_32.png)
Pegue uma amostra de uma distribuição de Wishart com a matriz de escala de identidade e calcule os valores próprios escalados.
![Click for copyable input](assets.pt-br/marchenko-pastur-distribution/In_72.png)
n = 10^4;
m = 10^3;
eigs = RandomVariate[
MatrixPropertyDistribution[Eigenvalues[x]/n,
x \[Distributed]
WishartMatrixDistribution[n, IdentityMatrix[m]]]];
Compare o resultado da amostra com a função densidade Marchenko-Pastur.
![Click for copyable input](assets.pt-br/marchenko-pastur-distribution/In_73.png)
Show[Histogram[eigs, {0.05}, "PDF", ImageSize -> Medium,
PlotTheme -> "Detailed"],
Plot[PDF[MarchenkoPasturDistribution[m/n], x], {x, 0, 1.8},
PlotTheme -> "Detailed", PlotLegends -> None, Exclusions -> None]]
![](assets.pt-br/marchenko-pastur-distribution/O_33.png)
Para , a matriz de Wishart é singular. Com probabilidade
, a distribuição tem uma massa no ponto em
.
![Click for copyable input](assets.pt-br/marchenko-pastur-distribution/In_74.png)
m = 500; n = 2 m;
CDF[MarchenkoPasturDistribution[n/m], 0]
![](assets.pt-br/marchenko-pastur-distribution/O_34.png)
Gere uma matriz de Wishart singular com covariância de identidade e calcule os valores próprios escalados.
![Click for copyable input](assets.pt-br/marchenko-pastur-distribution/In_75.png)
matrix = Transpose[#].# &[RandomVariate[NormalDistribution[], {m, n}]];
eigvs = Chop[Eigenvalues[matrix]/m];
Existe uma lacuna na densidade de valores próprios próximos de 0, e a coluna em 0 tem uma grande densidade.
![Click for copyable input](assets.pt-br/marchenko-pastur-distribution/In_76.png)
Histogram[eigvs, {0.05}, PDF, PlotRange -> 1, ChartStyle -> Orange,
ImageSize -> Medium]
![](assets.pt-br/marchenko-pastur-distribution/O_35.png)
Ajuste MarchenkoPasturDistribution aos valore próprios.
![Click for copyable input](assets.pt-br/marchenko-pastur-distribution/In_77.png)
edist = EstimatedDistribution[eigvs,
MarchenkoPasturDistribution[\[Lambda], 1]]
![](assets.pt-br/marchenko-pastur-distribution/O_36.png)
A função de distribuição de da distribuição ajustada mostra uma descontinuidade de salto na origem.
![](assets.pt-br/marchenko-pastur-distribution/O_37.png)