マルチェンコ・パスツール分布
マルチェンコ・パスツール分布は,行列次元 ,自由度
(どちらも
の割合で無限大になる傾向がある)のウィシャート行列の固有値の極限分布である.
については,分布は質点を持たず,確率密度関数は明確に定義される.
In[1]:=
![Click for copyable input](assets.ja/marchenko-pastur-distribution/In_70.png)
PDF[MarchenkoPasturDistribution[1/2], x]
Out[1]=
![](assets.ja/marchenko-pastur-distribution/O_31.png)
完全なWolfram言語入力を表示する
Out[2]=
![](assets.ja/marchenko-pastur-distribution/O_32.png)
恒等尺度行列のあるウィシャート分布からサンプルを取り,スケールされた固有値を計算する.
In[3]:=
![Click for copyable input](assets.ja/marchenko-pastur-distribution/In_72.png)
n = 10^4;
m = 10^3;
eigs = RandomVariate[
MatrixPropertyDistribution[Eigenvalues[x]/n,
x \[Distributed]
WishartMatrixDistribution[n, IdentityMatrix[m]]]];
サンプルとして取られた結果をマルチェンコ・パスツール密度関数と比較する.
In[4]:=
![Click for copyable input](assets.ja/marchenko-pastur-distribution/In_73.png)
Show[Histogram[eigs, {0.05}, "PDF", ImageSize -> Medium,
PlotTheme -> "Detailed"],
Plot[PDF[MarchenkoPasturDistribution[m/n], x], {x, 0, 1.8},
PlotTheme -> "Detailed", PlotLegends -> None, Exclusions -> None]]
Out[4]=
![](assets.ja/marchenko-pastur-distribution/O_33.png)
については,ウィシャート行列は特異行列である.確率
のとき,分布は
で質点を持つ.
In[5]:=
![Click for copyable input](assets.ja/marchenko-pastur-distribution/In_74.png)
m = 500; n = 2 m;
CDF[MarchenkoPasturDistribution[n/m], 0]
Out[5]=
![](assets.ja/marchenko-pastur-distribution/O_34.png)
恒等共分散を持つ特異ウィシャート行列を生成し,スケールされた固有値を計算する.
In[6]:=
![Click for copyable input](assets.ja/marchenko-pastur-distribution/In_75.png)
matrix = Transpose[#].# &[RandomVariate[NormalDistribution[], {m, n}]];
eigvs = Chop[Eigenvalues[matrix]/m];
0付近で固有値の密度にギャップがあり,0のビンで密度が高くなっている.
In[7]:=
![Click for copyable input](assets.ja/marchenko-pastur-distribution/In_76.png)
Histogram[eigvs, {0.05}, PDF, PlotRange -> 1, ChartStyle -> Orange,
ImageSize -> Medium]
Out[7]=
![](assets.ja/marchenko-pastur-distribution/O_35.png)
MarchenkoPasturDistributionを固有値にフィットする.
In[8]:=
![Click for copyable input](assets.ja/marchenko-pastur-distribution/In_77.png)
edist = EstimatedDistribution[eigvs,
MarchenkoPasturDistribution[\[Lambda], 1]]
Out[8]=
![](assets.ja/marchenko-pastur-distribution/O_36.png)
フィットされた分布の累積分布関数は,原点に不連続なジャンプがある.
完全なWolfram言語入力を表示する
Out[9]=
![](assets.ja/marchenko-pastur-distribution/O_37.png)