Marchenko–Pastur Distribution
Marchenko–Pastur distribution is the limiting distribution of eigenvalues of Wishart matrices as the matrix dimension and degrees of freedom
both tend to infinity with ratio
. For
, the distribution has no point mass and the probability density function is well-defined.
![Click for copyable input](assets.en/marchenko-pastur-distribution/In_70.png)
PDF[MarchenkoPasturDistribution[1/2], x]
![](assets.en/marchenko-pastur-distribution/O_31.png)
![](assets.en/marchenko-pastur-distribution/O_32.png)
Sample from a Wishart distribution with identity scale matrix and compute the scaled eigenvalues.
![Click for copyable input](assets.en/marchenko-pastur-distribution/In_72.png)
n = 10^4;
m = 10^3;
eigs = RandomVariate[
MatrixPropertyDistribution[Eigenvalues[x]/n,
x \[Distributed]
WishartMatrixDistribution[n, IdentityMatrix[m]]]];
Compare the sampled result with the Marchenko–Pastur density function.
![Click for copyable input](assets.en/marchenko-pastur-distribution/In_73.png)
Show[Histogram[eigs, {0.05}, "PDF", ImageSize -> Medium,
PlotTheme -> "Detailed"],
Plot[PDF[MarchenkoPasturDistribution[m/n], x], {x, 0, 1.8},
PlotTheme -> "Detailed", PlotLegends -> None, Exclusions -> None]]
![](assets.en/marchenko-pastur-distribution/O_33.png)
For , the Wishart matrix is singular. With probability
, the distribution has a point mass at
.
![Click for copyable input](assets.en/marchenko-pastur-distribution/In_74.png)
m = 500; n = 2 m;
CDF[MarchenkoPasturDistribution[n/m], 0]
![](assets.en/marchenko-pastur-distribution/O_34.png)
Generate a singular Wishart matrix with identity covariance and compute the scaled eigenvalues.
![Click for copyable input](assets.en/marchenko-pastur-distribution/In_75.png)
matrix = Transpose[#].# &[RandomVariate[NormalDistribution[], {m, n}]];
eigvs = Chop[Eigenvalues[matrix]/m];
There is a gap in the density of eigenvalues near 0, and the bin at 0 has a large density.
![Click for copyable input](assets.en/marchenko-pastur-distribution/In_76.png)
Histogram[eigvs, {0.05}, PDF, PlotRange -> 1, ChartStyle -> Orange,
ImageSize -> Medium]
![](assets.en/marchenko-pastur-distribution/O_35.png)
Fit MarchenkoPasturDistribution to the eigenvalues.
![Click for copyable input](assets.en/marchenko-pastur-distribution/In_77.png)
edist = EstimatedDistribution[eigvs,
MarchenkoPasturDistribution[\[Lambda], 1]]
![](assets.en/marchenko-pastur-distribution/O_36.png)
CDF of the fitted distribution shows a jump discontinuity at the origin.
![](assets.en/marchenko-pastur-distribution/O_37.png)