Calculez les valeurs propres symboliques
Spécifiez un opérateur Laplacien 1D.
In[1]:=
![Click for copyable input](assets.fr/compute-symbolic-eigenvalues/In_92.png)
\[ScriptCapitalL] = -Laplacian[u[x], {x}];
Spécifiez une condition aux limites de Dirichlet homogène.
In[2]:=
![Click for copyable input](assets.fr/compute-symbolic-eigenvalues/In_93.png)
\[ScriptCapitalB] = DirichletCondition[u[x] == 0, True];
Trouvez des expressions pour les 5 plus petites valeurs propres sur l'intervalle .
In[3]:=
![Click for copyable input](assets.fr/compute-symbolic-eigenvalues/In_94.png)
DEigenvalues[{\[ScriptCapitalL], \[ScriptCapitalB]}, u[x], {x, a, b},
5]
Out[3]=
![](assets.fr/compute-symbolic-eigenvalues/O_43.png)
Spécifiez un opérateur Airy.
In[4]:=
![Click for copyable input](assets.fr/compute-symbolic-eigenvalues/In_95.png)
\[ScriptCapitalL] = -Laplacian[u[x], {x}] + x u[x];
Trouvez les 5 plus petites valeurs et fonctions propres correspondantes.
In[5]:=
![Click for copyable input](assets.fr/compute-symbolic-eigenvalues/In_96.png)
{vals, funs} =
DEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]},
u[x], {x, 0, 1}, 5];
Les valeurs propres sont les racines d'une équation transcendantale.
In[6]:=
![Click for copyable input](assets.fr/compute-symbolic-eigenvalues/In_97.png)
vals[[1]] // TraditionalForm
Out[6]//TraditionalForm=
![](assets.fr/compute-symbolic-eigenvalues/O_44.png)
Calculez une valeur propre transcendantale avec une grande précision.
In[7]:=
![Click for copyable input](assets.fr/compute-symbolic-eigenvalues/In_98.png)
N[vals[[1]], 500] // TraditionalForm
Out[7]//TraditionalForm=
![](assets.fr/compute-symbolic-eigenvalues/O_45.png)
Visualisez les fonctions propres.
In[8]:=
![Click for copyable input](assets.fr/compute-symbolic-eigenvalues/In_99.png)
Plot[Evaluate[funs + Range[5]], {x, 0, 1}, ImageSize -> Medium,
PlotTheme -> {"Business", "Bare"}, AspectRatio -> 1]
Out[8]=
![](assets.fr/compute-symbolic-eigenvalues/O_46.png)