Связь округов США
Построить карту, показывающую соседние округи США.
Составить список всех округов в сопредельных континентальных штатах США.
In[1]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_28.png)
Length[counties =
Flatten[EntityClass["AdministrativeDivision",
"ContinentalUSStates"]["Subdivisions"]]]
Out[1]=
![](assets.ru/connectivity-of-us-counties/O_26.png)
Добавить к списку округ Колумбия, который не является подразделением ни одного из 48 сопредельных штатов.
In[2]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_29.png)
AppendTo[counties,
Entity["AdministrativeDivision", {"DistrictOfColumbia",
"DistrictOfColumbia", "UnitedStates"}]];
Составить список округов, граничащих друг с другом.
In[3]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_30.png)
bordering = EntityValue[counties, "BorderingCounties"];
Исключить из списка случаи, для которых информация о граничащих гео-объектах недоступна.
In[4]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_31.png)
Length[missingpos = Position[bordering, _Missing]]
Out[4]=
![](assets.ru/connectivity-of-us-counties/O_27.png)
In[5]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_32.png)
counties = Delete[counties, missingpos];
bordering = Delete[bordering, missingpos];
Построить график, отображающий сопредельные округи в США.
In[6]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_33.png)
Length[edges =
DeleteDuplicates[
Sort /@ Flatten[
MapThread[Thread[UndirectedEdge[##]] &, {counties, bordering}]]]]
Out[6]=
![](assets.ru/connectivity-of-us-counties/O_28.png)
In[7]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_34.png)
Graph[counties, edges]
Out[7]=
![](assets.ru/connectivity-of-us-counties/O_29.png)
Загрузить информацию о местоположении всех округов.
In[8]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_35.png)
pos = GeoPosition[EntityValue[counties, "Position"]]
Out[8]=
![](assets.ru/connectivity-of-us-counties/O_30.png)
Воспользуемся следующей картографической проекцией.
In[9]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_36.png)
proj = {"LambertAzimuthal",
"Centering" ->
Entity["City", {"Topeka", "Kansas", "UnitedStates"}]};
In[10]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_37.png)
projpos = First@GeoGridPosition[pos, proj];
В результате получим следующий график-вложение.
In[11]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_38.png)
graph = Graph[counties, edges, VertexCoordinates -> projpos]
Out[11]=
![](assets.ru/connectivity-of-us-counties/O_31.png)
Чтобы переместиться из округа Сан-Франциско в Манхэттен, необходимо посетить по крайней мере 67 округов США.
In[12]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_39.png)
Length[path = FindShortestPath[graph,
Entity[
"AdministrativeDivision", {"SanFranciscoCounty", "California",
"UnitedStates"}],
Entity[
"AdministrativeDivision", {"NewYorkCounty", "NewYork",
"UnitedStates"}]]]
Out[12]=
![](assets.ru/connectivity-of-us-counties/O_32.png)
In[13]:=
![Click for copyable input](assets.ru/connectivity-of-us-counties/In_40.png)
HighlightGraph[graph, PathGraph[path]]
Out[13]=
![](assets.ru/connectivity-of-us-counties/O_33.png)