Распределение и обратное распределение Уишарта
Распределение Уишарта - это распределение ковариационной матрицы с выборкой, полученной из независимых многомерных случайных векторов. Оно является обобщением (хи-квадрат) распределения в многочисленных измерениях. Распределение формируется естественным образом в многомерном статистическом анализе, таком как регрессия, ковариантность и др.
Сгенерируйте случайную положительную определённую матрицу для использования в качестве параметров для распределения Уишарта.
![Click for copyable input](assets.ru/wishart-and-inverse-wishart-distributions/In_24.png)
\[CapitalSigma] = DiagonalMatrix[RandomReal[10, 5]];
Матрицы из распределения Уишарта симметричны и положительно определены. »
![Click for copyable input](assets.ru/wishart-and-inverse-wishart-distributions/In_25.png)
dist = WishartMatrixDistribution[30, \[CapitalSigma]];
mat = RandomVariate[dist];
![Click for copyable input](assets.ru/wishart-and-inverse-wishart-distributions/In_26.png)
SymmetricMatrixQ[mat] && PositiveDefiniteMatrixQ[mat]
![](assets.ru/wishart-and-inverse-wishart-distributions/O_12.png)
Обратное распределение Уишарта - это распределение обратных матриц из распределения Уишарта. »
![Click for copyable input](assets.ru/wishart-and-inverse-wishart-distributions/In_27.png)
invdist =
InverseWishartMatrixDistribution[30, Inverse[\[CapitalSigma]]];
invmat = RandomVariate[invdist];
Матрицы из обратного распределения Уишарта симметричны и положительно определены.
![Click for copyable input](assets.ru/wishart-and-inverse-wishart-distributions/In_28.png)
SymmetricMatrixQ[invmat] && PositiveDefiniteMatrixQ[invmat]
![](assets.ru/wishart-and-inverse-wishart-distributions/O_13.png)
Сравните распределение собственных значений для матриц из распределения и обратного распределения Уишарта.
![Click for copyable input](assets.ru/wishart-and-inverse-wishart-distributions/In_29.png)
eigs = Flatten[
RandomVariate[
MatrixPropertyDistribution[Eigenvalues[x], x \[Distributed] dist],
10^4]];
inveigs =
Flatten[RandomVariate[
MatrixPropertyDistribution[Eigenvalues[x]^-1,
x \[Distributed] invdist], 10^4]];
![](assets.ru/wishart-and-inverse-wishart-distributions/O_14.png)
Для любого ненулевого вектора и матрицы Уишарта
со шкалой матрицы
, статистические
имеют
(хи-квадрат) распределение.
![Click for copyable input](assets.ru/wishart-and-inverse-wishart-distributions/In_31.png)
y = #/Sqrt[#.\[CapitalSigma].#] &[RandomReal[1, 5]];
data = RandomVariate[
MatrixPropertyDistribution[y.w.y,
w \[Distributed] WishartMatrixDistribution[30, \[CapitalSigma]]],
10^4];
![Click for copyable input](assets.ru/wishart-and-inverse-wishart-distributions/In_32.png)
Show[Histogram[data, Automatic, PDF, PlotTheme -> "Detailed"],
Plot[PDF[ChiSquareDistribution[30], x], {x, 0, 80}],
ImageSize -> Medium]
![](assets.ru/wishart-and-inverse-wishart-distributions/O_15.png)